# YASARA MOVIE
# TOPIC:    6. Multimedia
# TITLE:    6.8. Rattle snake poison
# REQUIRES: View 8.10.4
# AUTHOR:   Elmar Krieger
# LICENSE:  GNU GPL
# DESCRIPTION: A little animation of rattle snake poison and its inhibitor

# Change working directory to the place of this macro
# (so that we don't have to specify paths when loading stuff).
CD (MacroDir)

# Initialize
Start:
Clear
UserInput Off
CoordSys Left
Console Off
HUD Off
HideMessage

# Set basic graphics styles
StickRadius 50
BallRadius 50
ColorBG cycle
ColorBonds Grey
LightSource 50,50
Fog 60

# Load the snake
LoadPNG snake
ShowImage snake


# Load the poison+to-be-inhibitor
orientation='-55,215,-20'
LoadSce complex
"""
LoadYOb complex
CenterObj complex
OriObj complex,(orientation)
# Remove the TER entry before the last atom
JoinAtom 1629
# Split the complex, keeping the common coordinate system
SplitObj complex,Center=No
"""
RenameObj 1,poison
RenameObj 2,ligand
PosObj poison,Y=-20,Z=1500
SwitchObj poison,off
OriObj poison,Alpha=152,Beta=43,Gamma=-32
OriObj ligand,Alpha=293,Beta=219,Gamma=-54
LabelObj poison,"Venom",Height=10,Color=Red
LabelObj ligand,"Antidote",Height=1.5,Color=Green
Style Ribbon,Stick
BallStickObj ligand
ColorObj ligand,160
# Bring up the ligand
PosObj ligand,X=7.2,Y=20,Z=14
Wait 100
AutoMoveToObj ligand,Y=6,Steps=150

# Wait a bit, them zoom into the mouth
Wait 100
steps=500
for i=1 to steps
  step=(0.+i)/steps
  print 'Width=((1.-step)*1024+step*6),Height=((1.-step)*768+step*4)'
  ShowImage snake,X=(183.*step),Y=(170.*step),Width=((1.-step)*348+step*6),Height=((1.-step)*240+step*4)
  Wait 1

# Show the poison
SwitchObj poison,on
AutoRotateObj poison,X=-0.5
AutoMoveToObj poison,X=0,Y=-18,Z=21,Steps=400
Wait 300

# Zoom out
AutoMoveTo Z=63,Steps=100

# Dock them
AutoRotateObj all,0,0,0
AutoRotateToObj all,(orientation),Steps=150,Wait=No
AutoMoveToObj poison,1,-1,66,Steps=150,Wait=No
AutoMoveToObj ligand,-15,2,59,Steps=150
UnlabelObj all
AutoMoveToObj ligand,1,-1,66,Steps=200

# Zoom in and show surface
AutoMoveTo 6.5,5,17,Steps=150
"""
SurfPar molecular=Gaussian
AddEnvObj poison
for i=-20 to 20
  ShowSurfAtom GlobalX<(i) Obj poison,molecular,dynamic,OutCol=ff6800,OutAlpha=50,InCol=800000,InAlpha=0
  Wait 1
"""
Wait ContinueButton
Stop